Disquette de boot MS-DOS

avec

prise en charge réseau TCP/IP

 

 

Cette page explique comment créer et utiliser une disquette de démarrage sous MS-DOS avec prise en charge réseau TCP/IP pour différents types de cartes réseau.

 

Plan de ce document :

  1. Présentation
  2. Principe
  3. Les fichiers clef
  4. Analyse du fonctionnement
  5. Analyse des fichiers config.sys et autoexec.bat
  6. Les astuces
  7. Le paramètrage
  8. L'utilisation
    8.1 Cas de Windows 2003 serveur
  9. Ajout de cartes réseau
  10. Le contenu de la disquette
  11. Téléchargements (Télécharger)
  12. Extensions de fonctionnalités
  13. Certification "BootNet"
  14. Evolutions des versions complètes

 

 

I) - PRESENTATION

La disquette dont fait l'objet cet article permet de démarrer une machine avec connexion réseau à une (des) machine(s) "serveur", en domaine ou non. La particularité est la prise en charge de bon nombre de cartes réseau du marché. De plus, cette disquette est modulaire et permet très simplement d'ajouter de nouvelles fonctionnalités.

Nous appelerons cette disquette "BootNet".

 

 

II) - PRINCIPE

La disquette est amorçable en MS-DOS version 98. Les fichiers config.sys et autoexec.bat prennent en charge des scripts permettant de détecter le type de carte réseau de la machine et chargent le pilote approprié. Le lancement des services TCP/IP est ensuite initié pour finalement se connecter aux partages d'une machine considérée comme serveur.

 

 

III) - LES FICHIERS CLEF

La disquette doit être bootable et si possible sous MS-DOS version 98 (créée avec Windows 98SE précédement patché avec le correctif Q263044 (fdisk ne gère pas correctement les disques de taille supérieure à 64 Go - Cf patchs pour 98/98SE)

Xmsdsk.exe (20 Ko) : Freeware, il permet la création d'un disque virtuel. La taille du disque est paramètrable ainsi que la lettre d'affectation. Télécharger xmsdsk.zip (74 Ko).

Nicdet.exe (69 Ko) : C'est le moteur principal de cette disquette. Il est fourni par l'éditeur Power Quest et permet de détecter la carte réseau implantée dans le PC afin d'installer les pilotes adéquats. Il est utilisé en association avec le fichier Nicdet.ini (7 Ko) qui doit être correctement renseigné avec les cartes réseau à détecter.
En effet, chaque carte possède une signature unique codant le nom du fabricant, le type de carte, le modèle (ex, VEN_1282&DEV_9102&SUBSYS_82120498), et c'est le fichier Nicdet.ini qui fait la liaison logique entre le modèle de carte et le pilote à utiliser (voir la section [PCI] du fichier).
Reprenons l'exemple correspondant à cette signature...
La ligne VEN_1282&DEV_9102&SUBSYS_82120498=DAVICOM PCI LongRun Adapter,DM9PCI$,Dm9pci.dos signifie que nous avons affaire à une carte dont le type est "DAVICOM PCI LongRun Adapter" et dont le pilote est le fichier Dm9pci.dos.
Il faudra donc intégrer le fichier Dm9pci.dos dans le fichier bibliothèque NIC.lzh.

Gdisk.exe (177 Ko) : Développé par Symantec, il agit comme fdsik.exe de Microsoft mais propose des fonctionnalités avancée comme la possibilité de partitionner et formater en une seule opération.

lha.exe (34 Ko) : Le vieil utilitaire de l'époque MS-DOS joue aussi un rôle essentiel puisqu'il permet de compresser/décompresser le fichier de bibliothèque. Sa taille réduite ne lui enlève pas ses performances en terme de rapidité et de taux de compression.

UTILS.lzh (139 Ko) : Bibliothèque d'utilitaires MS-DOS, créé avec lha.exe.

NIC.lzh (213 Ko) : Bibliothèque des pilotes des cartes réseau.

NET.lzh (382 Ko) : Bibliothèque des applications réseau.

 

 

IV) - ANALYSE DU FONCTIONNEMENT

Le script contenu sur la disquette effectue plusieurs grandes étapes :

 

 

V) - ANALYSE DES FICHIERS CONFIG.SYS & AUTOEXEC.BAT

Ces 2 fichiers regroupent plusieurs commandes que nous allons éclaircir...

       
Fichier config.sys
Gestionnaire mémoire haute
DOS en mémoire haute dans les UMB
20 handles
20 buffers
Pile DOS standard (facultatif)
Ramdrive Microsoft (4 Mo)
Dernier lecteur Z:
Gestionnaire de noms longs et fonctions réseau
Ramdrive de 4Mo en R:
Copie du "command.com" dans cmd.lhz
Décompression du "command.com" sur R:
Lance ce nouvel interpreteur de commande sur R:
device=himem.sys
dos=high,umb
files=20
buffers=20
'stacks=9,256
devicehigh=ramdrive.sys /E 4096
lastdrive=z
device=ifshlp.sys

 

 

       
Fichier autoexec.bat
Pas d'écho des commandes @ECHO OFF
  rem
rem --------------------------------------------------
rem -----  Script de base permettant d'installer -----
rem -----     un pilote de carte réseau et de    -----
rem -----        lancer le protocole TCP/IP      -----
rem --------------------------------------------------
rem
rem







Renseigner si besoin sinon
laisser vide (ex. set LOGIN=)

AUTOLOG=Y : authentification
auto (il faut alors que LOGIN et
PASSWORD soient définis)
AUTOLOG=N : authentification
manuelle
En Workgroup laisser vide.











Initialisation variable env.

Appel du batch de détection de
lettre de lecteur.
Pas de ramdrive -> Quitte




Copie "command.com" dans cmd.lhz
Décompression "command.com" sur le ramdrive.
Lance le nouvel interpreteur de commande sur le ramdrive

rem
REM Partie 1 : Initialisation des variables utilisateur
Rem ---------------------------------------------------
rem
rem Commenter ou décommenter en fonction des besoins
rem
rem Login et password
set LOGIN=inst
set PASSWRD=inst
rem
rem
rem Methode d'authentification (cf KB142703)
rem set AUTOLOG=Y
set AUTOLOG=N
rem
rem Domaine d'authentification
rem set DOMAINE=MyDomain
set DOMAINE=
rem

rem
REM Partie 1 bis : Installation du RAMDRIVE
Rem ---------------------------------------
call entete.bat
set EXPAND=YES
set DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
call Setramd.bat %LglDrv%
if "%RAMD%"=="" GOTO End
rem

rem
REM Partie 1 ter : Initialisation du RAMDRIVE
Rem -----------------------------------------
a:\lha.exe a /n2 %RAMD%:\cmd.lzh a:\command.com
a:\lha.exe e /n2 %RAMD%:\cmd.lzh %RAMD%:\
rem shell=%RAMD%:\command.com /E:1024 /P
rem





Permet de savoir si finir le batch
Init de COMSPEC
Prompt MS-DOS classique
Initialise le dossier temporaire

Défini le chemin de recherche
Va sur le Ramdisque

rem
REM Partie 2 : Initialisation des variables système
Rem -----------------------------------------------
Rem
set QUIT=N
set COMSPEC=%RAMD%:\command.com
PROMPT $P$G
set temp=%RAMD%:\
set tmp=%RAMD%:\
path=%RAMD%:\;%RAMD%:\net;
%RAMD%:




Création dossier \Net sur Ramdisk
Copie de certains fichiers
Note : "> nul" permet de ne pas
afficher les messages du type
"1 fichier copié"

Test présence biblio d'outils
Gestion d'erreur si absence




Raffraichissement écran
Décompression des outils
sur le Ramdisk
Clavier français


Appel du module de gestion de C
Gestion du param de retour

rem
REM Partie 3 : Décompression des outils
Rem -----------------------------------
md %RAMD%:\net
copy a:\lha.exe %RAMD%:\ /Y > NUL
copy a:\nicdet.ini %RAMD%:\ /Y > NUL
copy a:\*.bat %RAMD%:\ /Y > NUL
copy a:\SCRIPT.TXT %RAMD%:\ /Y > NUL

if NOT exist a:\utils.lzh echo Le fichier contenant les outils est manquant.
if NOT exist a:\utils.lzh echo L'installation ne peut continuer.
if NOT exist a:\utils.lzh echo.
if NOT exist a:\utils.lzh pause
if NOT exist a:\utils.lzh GOTO End

call entete.bat
echo D‚compression des utilitaires sur le disque virtuel...
lha e /n a:\utils.lzh %RAMD%:\ *.* > nul
keyb fr

rem **** Détection présence disque C ****
call Gere_C
if "%QUIT%"=="Y" GOTO End





Raffraichissement écran
Test présence biblio pilotes
Gestion d'erreur si absence




Test présence biblio applis réseau
Gestion d'erreur si absence





Décompression des pilotes



Décompression des applis réseau



Test présence fichier Net.exe
S'il n'existe pas : Pb




Régénération du MBR de C:

rem
REM Partie 4 : Décompression des bibliothèques
Rem ------------------------------------------
:Connect
call entete.bat

if NOT exist a:\nic.lzh echo Le fichier contenant les pilotes est manquant.
if NOT exist a:\nic.lzh echo L'installation ne peut continuer.
if NOT exist a:\nic.lzh echo.
if NOT exist a:\nic.lzh pause
if NOT exist a:\nic.lzh GOTO End

if NOT exist a:\net.lzh echo Le fichier des application r‚seau est manquant.
if NOT exist a:\net.lzh echo L'installation ne peut continuer.
if NOT exist a:\net.lzh echo.
if NOT exist a:\net.lzh pause
if NOT exist a:\net.lzh GOTO End

echo D‚compression des pilotes de cartes sur le disque virtuel...
lha e /m /n a:\nic.lzh %RAMD%:\net\ *.* > nul
rem
call entete.bat
echo D‚compression des utilitaires r‚seau sur le disque virtuel...
lha e /m /n a:\net.lzh %RAMD%:\net\ *.* > nul
rem
call entete.bat
cd net
if NOT exist net.exe echo ProblŠme lors de la d‚compression des fichiers.
if NOT exist net.exe echo L'installation ne peut continuer.
if NOT exist net.exe echo.
if NOT exist net.exe pause
if NOT exist net.exe GOTO End

rem fdisk /mbr > nul






Détection de la carte réseau
Si problème termine





Chargement des pilotes de la carte
Si problème termine




Détection de la vitesse du réseau
Si problème termine





Installation de TCP/IP
Si problème termine




Montage de NetBIOS sur TCP/IP
rem
REM Partie 5 : Installation de la carte reseau
Rem ------------------------------------------
call entete.bat
echo D‚tection de la carte r‚seau...
nicdet
if errorlevel 1 goto End

delay 3000 > nul

echo.
echo Chargement des pilotes de la carte et montage de TCP/IP
rem net init /dynamic
net initialize /dynamic > nul
if errorlevel 1 echo ProblŠme NET INITIALIZE. Arrˆt de l'installation.
if errorlevel 1 goto End

call entete.bat
echo D‚tection de la vitesse du r‚seau...
netbind > nul
if errorlevel 1 echo ProblŠme NETBIND. Arrˆt de l'installation.
if errorlevel 1 goto End

echo.
echo Montage de TCP/IP en r‚sidant
tcptsr > nul
if errorlevel 1 echo ProblŠme TCPTSR. Arrˆt de l'installation.
if errorlevel 1 goto End

echo .
echo Montage de la pile TCP/IP 1.0 pour les clients MS-DOS
tinyrfc > nul
rem if not errorlevel 0 echo ProblŠme TINYRFC. Arrˆt de l'installation.
rem if not errorlevel 0 goto End







Choix autologon ou Logon manuel


Gestion d'erreur du Logon



Partie Logon manuel
Gestion d'erreur du Logon
rem
REM Partie 6 : Authentification
Rem ---------------------------
call entete.bat
echo Pr‚paration de la s‚quence d'authentification
echo.
if "%AUTOLOG%"=="N" GOTO LogMan
if "%DOMAINE%"=="" net logon %LOGIN% %PASSWRD% /yes /savepw:no
if NOT "%DOMAINE%"=="" net logon %LOGIN% %PASSWRD% /domain:%DOMAINE% /yes /savepw:no
if errorlevel 1 echo ProblŠme NET LOGON. Arrˆt de l'installation.
if errorlevel 1 goto End
GOTO LogOK

:LogMan
net start basic
if errorlevel 1 echo ProblŠme NET START. Arrˆt de l'installation.
if errorlevel 1 goto End
:LogOK






Lancement script spécifique
rem
REM Partie 7 : Lancement script spécifique
Rem --------------------------------------
call entete.bat
echo Lancement du script "My Script"
delay 2000 > nul
call MyScript.bat
Etiquette de fin
Libération des variables...
:End
set LOGIN=
set PASSWRD=
set SOFT=
set AUTOLOG=
set DOMAINE=
set RAMD=
set REP1=
set QUIT=

 

Note : les caractères accentués apparaîssent erronés. Ceci est normal et est dù au décalage de codes des caractères entre l'ASCII MS-DOS et les caractères sous Windows.

 

 

VI) - LES ASTUCES

Elles sont nombreuses !

Le gain de place :
C'était l'objectif principal ! MS-DOS permet de lancer des exécutables directement dans le config.sys. Il devient alors possible d'installer le disque virtuel à partir du config.sys et d'utiliser l'utilitaire lha.exe pour "cloner" l'interpreteur de commandes de la disquette afin de le restituer sur le ramdisque puis de lancer directement ce nouvel interpreteur au niveau du disque virtuel.

L'installation du Ramdrive :
En utilisant les outils MS-DOS classiques (Ramdrive.sys), la lettre d'installation est incontrôlable... Il faut donc utiliser un batch de détection de la lettre attribuée.

Détection de l'existence d'une partition FAT
A l'aide de commandes MS-DOS classiques, il est possible de détecter si C existe. Dans le cas précis de cette disquette, le batch demande alors s'il faut partitionner, continuer le déroulement ou simplement quitter (Cf module Gere_C.bat)

Suppression des partitions, repartitionnement et formatage
Fonction uniquement utilisé par le module Gere_C.bat. Agissant comme l'utilitaire Fdisk.exe de Microsoft, l'utilitaire évolué Gdisk.exe de Power Quest permet d'effectuer en un seul reboot toutes ces opérations.

FDISK /mbr :
Par expérience, si un système Linux était installé sur la machine, il faut reconstruire le Master Boot Record du disque dur afin de pouvoir redémarrer correctement sans essuyer un "Lilo" en haut d'écran. Un virus peut aussi rester logé dans le MBR c'est pourquoi le fait d'invoquer la reconstruction du MBR peut être une sage précaution.

Détection de la carte réseau :
L'utilitaire Nicdet.exe permet de détecter la carte réseau en place, ceci à la seule condition que le fichier associé Nicdet.ini soit correctement renseigné avec les cartes réseau à détecter.
Ce fichier est de base généré par "PowerQuest Drive Image Pro" sous Windows mais en fonction des cartes réseau à prendre en charge, il peut être fortement utile de le corriger avec un éditeur de texte tel que Notepad.exe.

Le fichier de cet article prend en charge les cartes suivantes :

       
3COM Toutes versions de la serie 3C90x
3C920 compatible
3C940 compatible
3C2000 compatible
3CN3AC1556B mini PCI
ACCTON

EN2242 Series MiniPCI Fast Ethernet
CheetahPower (AC-EN3207)
LM2247(A) Series Mini-PCI Fast Etherner
LM2247 Series Mini-PCI Fast Ethernet
LM1247 Series PCI Fast Ethernet
EN1207F Series Fast Ethernet

AMD AMD PCnet
ADMtek

AN993 (10/100 PCI)

ASANTé

FAST 10/100 PCI adapter
FAST 10/100 PCI REV.B adapter

BROADCOM Broadcom 570x Gigabit Integrated Controller
Broadcom NetXtreme Gigabit Ethernet
Broadcom NetXtreme Fast Ethernet
CNET CNET PRO200WL PCI Fast Ethernet Adapter
CNET PRO200 PCI Fast Ethernet Adapter
COMPAQ Ethernet NIC
Fast Ethernet NIC
Fast Ethernet NIC (Rev A & B)
Fast Ethernet Module
Fast Ethernet Upgrade Module
Fast Ethernet Embedded Controller with WOL
Gigabit Module
Gigabit NIC
Gigabit Server Adapter
NetFlex-3
Netelligent 10/100
DAVICOM DAVICOM 9102/A PCI Fast Ethernet Adapter
DAVICOM 1/10/100 PCI Fast Ethernet Adapter
DAVICOM LongRun/10/100 PCI Fast Ethernet Adapter
DAVICOM PCI HomeRun Adapter
DAVICOM PCI LongRun Adapter
DAVICOM PCI Fast Ethernet Based Adapter
DAVICOM 9102A Full Based Switching Adapter
DAVICOM 9102A Half Based Switching Adapter
DAVICOM 10 Base-T PCI Ethernet Adapter
D-LINK D-Link DE-530 PCI Ethernet Adapter
D-Link DE-530+ PCI Ethernet Adapter
D-Link DFE-530TX PCI Fast Ethernet Adapter
D-Link DFE-500TX PCI Fast Ethernet Adapter (Rev A/B/C/D/E)
D-Link DFE-530TX+ PCI Fast Ethernet Adapter
HP J2585B DeskDirect 10/100 NIC
J2585A DeskDirect 10/100VG NIC
IBM IBM 10/100 Etherjet
INTEL INTEL(R) PRO/100+ PCI Adapter
INTEL(R) PRO/1000 PCI Adapter ou 82540/82544 chipset
INTEL(R) PRO/1000 MT
KINGSTON Kingston EtheRx PCI 10/100 Fast Ethernet Adapter (KNE110TX)
Linksys LNE 100TX Fast Ethernet Adapter
LINKSYS Linksys LNE 100TX Fast Ethernet Adapter
MARVEL Marvell Yukon Gigabit
NS NetGear FA311/FA312 (chipset MacPhyter 10/100Mb MAC & PHY)
REALTEK Realtek RTL8169/8110 Gigabit Ethernet Family PCI Fast Ethernet NIC
Realtek RTL8168/8111 Gigabit Ethernet Family PCI Fast Ethernet NIC
Realtek RTL8136/8111 Gigabit Ethernet Family PCI Fast Ethernet NIC
Realtek RTL8139/810X Family PCI Fast Ethernet NIC
Realtek RTL8029AS Combo 10Mbits PCI Ethernet NIC
Realtek RTL8029 PCI Ethernet NIC
Realtek RTL8019 PCI Ethernet NIC
SIS SiS 900-Based PCI Fast Ethernet Adapter
Integrated 10/100 Ethernet Controller
SMC SMC EtherEZ (SMC8416 Series)
SMC EtherPower 10/100 Ethernet Adapter (SMC8432 Series)
SMC EtherPower 10/100 Ethernet Adapter (SMC9332 Series)
SMC EtherPower 10/100 Ethernet Adapter (SMC9334 Series)
SMC EtherPower ii 10/100 Ethernet Adapter (SMC9432 Series)
SMC EZ Card 10/100 PCI (SMC1211 Series)
VIA VIA Rhine II Fast Ethernet Adapter
VIA Rhine III Fast Ethernet Adapter
VIA Rhine III Management Adapter
VIA VT86C100A Rhine Fast Ethernet Adapter
ZONET Realtek RTL8139C PCI Fast Ethernet Adapter

 

 

 

VII) - LE PARAMETRAGE

En agissant sur 2 fichiers textes, la disquette est paramètrable simplement :

La connexion au serveur :
Elle peut se faire en tant que client avec adresse IP fixe ou en client DHCP. Il faut pour cela modifier le fichier Nicdet.ini dans la section [TCPIP] en fonction du tableau suivant :

       
Variable
Client DHCP
IP fixe

DEFAULTGATEWAY0=
SUBNETMASK0=
IPADDRESS0=
DISABLEDHCP=0

laisser vide
laisser vide
laisser vide
0
xxxx,xxxx,xxxx,xxxx
xxxx,xxxx,xxxx,xxxx
xxxx,xxxx,xxxx,xxxx
1

 

L'authentification :
Elle peut s'effectuer sur un domaine ou simplement sur une machine avec un partage. Dans le cas de ce tutoriel, elle s'effectue sur une machine simple avec le compte "inst". La modification du fichier Nicdet.ini dans la section [NETWORK] permettra d'adapter les paramètres en fonction du tableau suivant :

       
USERNAME = Mettre un nom de compte utilisateur ayant les droits nécessaires
sur les serveurs pour accèder aux fichiers
Si vide, le système demandera un nom.
Le mot de passe sera demandé lors de l'exécussion.
WORKGROUP =

Si le réseau est en Workgroup, entrer son nom ici.
Si le réseau est en Domaine, laisser vide.

LOGONDOMAIN = Si le réseau est en Domaine, entrer son nom ici.
Si le réseau est en Workgroup, laisser vide.

 

Ne pas oublier de paramètrer la variable "DOMAINE" du fichier autoexec.bat en conséquence à l'aide de la commande set DOMAINE=...

NB : Prévoir au niveau du (des) serveur(s) un compte "inst" ayant les droits nécessaires.

 

 

VIII) - L'UTILISATION

Simple... Il suffit d'insérer la disquette dans l'ordinateur et de mettre celui-çi sous tension.
Le chargement est un peu lent mais le process affiche des messages clairs à l'écran permettant de suivre le bon déroulement des opérations.
Les étapes s'enchainent et une bonne minute plus tard, en fonction du paramètrage, une authentification manuelle est requise : il suffit alors d'entrer le login et valider, s'en suit la demande du mot de passe et valider. Une ultime question propose de mémoriser le mot de passe, il vaut mieux répondre "N" et valider. Le scripts utilisateur peut alors s'exécuter...
Attention, ce dernier point est important. En répondant "Y", la mémorisation du mot de passe s'effectue dans un fichier sur le disque virtuel et ce fichier est facile à lire. Le danger reste toutefois modéré puisque le Ramdisque est effacé lors de l'extinction du PC.

1) Cas particulier : Windows 2003 serveur

En effet, la connectivité des vieux clients DOS avec 2003 serveur peut parfois poser problèmes. La sécurité étant renforcée, il se peut que BootNet ne puisse pas se connecter à un 2003 serveur Controleur de domaine.
Il suffit dans ce cas de jouer avec les GPO afin de rétablir le paramètrage nécessaire qui consiste à désactiver la signature SMB (Cf article Microsoft 325379)

Afin d'appliquer immédiatement les changements, exécuter la commande suivante en ligne : gpupdate /target:computer /force
(noter que pour appliquer une stratégie utilisateur, il faut entrer gpupdate /target:user /force).

 

 

IX) - AJOUT DE CARTES RESEAU

La partie la plus délicate consiste à ajouter de nouveaux pilotes pour la prise en charge de cartes réseaux supplémentaires. Cette opération s'effectue sur 2 axes : la modification du fichier Nicdet.ini à l'aide d'un éditeur de texte tel que Notepad.exe et la modification de l'archive NIC.lzh à l'aide de l'utilitaire lha.exe.

Pour la collecte des pilotes d'une nouvelle carte réseau, il faut télécharger la partie DOS ainsi que la partie Windows 98 des pilotes.
Dans la partie Windows, repérer les fichiers d'extension ".inf" et les ouvrir à l'aide de l'éditeur de texte.
Repérer en début de fichier une section peu après celle nommé [Manufacturer] contenant une (des) définition(s) de signature de type PCI\VEN_1282&DEV_9102&SUBSYS_8212049
Repérer ensuite la section [Strings]. Des variables sont assignées aux descriptions de cartes. Il faut alors associer chaque signature à sa description en suivant les variables, ce qui est parfois un véritable cass-tête. Le résultat escompté est du type PCI\VEN_1282&DEV_9102&SUBSYS_8212049=DAVICOM PCI LongRun Adapter.
Ouvrir ensuite le fichier Protocol.ini de la partie DOS des pilotes. Le nom du pilote y est inscrit en première ligne dans la variable DriverName (ex : DriverName=DM9PCI$).
Ceci ressemble fortement au nom de pilote DM9PCI.DOS que l'on doit trouver dans la partie DOS des pilotes. Il ne reste plus qu'à complèter l'entrée du fichier Nicdet.ini avec la chaine complète : VEN_1282&DEV_9102&SUBSYS_8212049=DAVICOM PCI LongRun Adapter,DM9PCI$,Dm9pci.dos, chaque élément étant séparé par une virgule.

Il ne reste plus qu'à ajouter le fichiers pilote à l'archive Nic.lzh. Pour cela, utiliser la commande lha a Nic.lzh NomFichier.ext (pour notre exemple, ceci se traduit par lha a Nic.lzh Dm9pci.dos).
Si plusieurs fichiers sont à ajouter, il peut être utile d'utiliser les jokers (? et *) : lha a Nic.lzh *.ext
(Toutes les informations concernant l'utilitaire lha.exe sont accessibles par la commande lha /?)

 

 

X) - LE CONTENU DE LA DISQUETTE

La disquette est composée d'un système, des fichiers config.sys et autoexec.bat, de 3 archives (les bibliothèques), de quelques scripts batchs et autres fichiers explicités précédemments.

A titre indicatif, voici le listing du contenu de la disquette :

 

 

XI) - TELECHARGEMENTS

La disquette... 2 déclinaisons : BootNetSe (1,3 Mo) ou BootNetMe (plus maintenue depuis le 19/04/2005).
2 déclinaisons fonctions de l'interpréteur de commande utilisé : 98SE ou Millenium. Il peut y avoir des blocages avec l'une ou l'autre version - Utiliser la disquette qui fonctionne avec votre système.
La disquette est téléchargeable dans un format auto-extractible. Il suffit de double-cliquer sur le fichier téléchargé en ayant pris soins au préalable de mettre une disquette vierge dans le lecteur A:
Noter que cette image de disquette a été réalisée avec le gratuit FloppyImage V1.5.2 disponible en téléchargement sur ce site.

Le Ramdisque (plus utilisé dans les versions actuelles) : xmsdsk.zip (74 Ko). Cette archive contient quelques utilitaires dont xmsdsk.exe et fichiers d'informations. Noter que cet utilitaire n'est plus utilisé à partir de la version du 20 janvier 2005.

IMPORTANT :
A compter du 27 novembre 2006, seules seront proposées des "évolutions" de la disquette sous forme d'un fichier ZIP. Il suffira alors de décompresser l'archive et de copier les fichiers sur la disquette dite "de base".
Les évolutions sont cumulatives, c'est à dire qu'une évolution reprend la totalité des évolutions précédentes.

Télécharger
16/11/2007
Evolution
Ajout de la carte AMD PCnet de VMware Server (merci à Jean-Marc)
Télécharger
13/04/2007
Evolution
Correction de la prise en charge des cartes Broadcom pour DELL 745
Télécharger
21/03/2007
Evolution
Ajout de la prise en charge des cartes Broadcom pour DELL D820
Amélioration de la prise en charge des cartes INTEL Pro 1000
Télécharger
20/12/2006
Evolution
Ajout des cartes Broadcom 570x Gigabit Integrated Controller
Amélioration de la prise en charge des cartes Broadcom
Télécharger
27/11/2006
===== Version de base - A télécharger obligatoirement =====

 

 

XII) - EXTENSIONS DE FONCTIONNALITES

La structure présentée est une base de travail. Il est maintenant possible d'y adjoindre des modules de traitement spécifiques.
En effet, les variables d'environnement sont globales et sont donc récupérables d'un batch à un autre. Il devient donc possible de passer des paramètres de retour.
Ainsi, ce module de gestion de présence d'une partition C. Si le système ne voit pas de partition C valide, il propose un choix d'actions à entreprendre.
Ce module est à placer en fin de partie 3.

       
Fichier Gere_C.bat







Recherche dans la chaine "C:"
Si oui, il y a un disque C
Si non, on va à No_C


Raffraichissement écran


Demande quelle action effectuer




Si partitionnement demande taille
Si connection, FIN
Si quitte, init var Quit et FIN






La valeur entrée au clavier est
retournée dans SIZE









Efface toutes les partitions
Refait le MBR
Partition primaire de SIZE Go

rem
REM Module de gestion présence disque C
Rem -----------------------------------
:Debut
call entete.bat
set QUIT=
%comspec% /F /C dir C:\ | FIND "C:" > NUL
if errorlevel 1 GOTO No_C
GOTO Fin

:No_C
call entete.bat
Echo Il semble que le disque dur ne soit ni partitionn‚ ni format‚
Echo.
CHOICE /C:PCQ /N [P]artitionner et Formater, [C]onnecter au r‚seau ou [Q]uitter ?
if errorlevel 1 SET REP1=PART
if errorlevel 2 SET REP1=CONN
if errorlevel 3 SET QUIT=Y

if "%REP1%"=="PART" GOTO GetSize
if "%REP1%"=="CONN" GOTO Fin
if "%QUIT%"=="Y" GOTO Fin

:GetSize
call entete.bat
Rem On gère la demande de taille et on partitionne
echo Vous avez demand‚ une partitionnement/formatage du disque...
echo.
echo Entrer la taille de la partition (en Go) ou [A]nnuler ou [Q]uitter
getvar SIZE Puis [Enter] pour valider.
echo.
if "%SIZE%"=="" GOTO GetSize
if "%SIZE%"=="q" set QUIT=Y
if "%SIZE%"=="Q" set QUIT=Y
if "%SIZE%"=="a" GOTO Debut
if "%SIZE%"=="A" GOTO Debut

if "%QUIT%"=="Y" GOTO Fin

GDISK.exe 1 /y /del /all > nul
GDISK.exe 1 /y /MBR > nul
GDISK.exe 1 /y /CRE /PRI /SZ:%SIZE%000 /FOR /Q > nul
reboot.exe
:Fin

 

 

XIII) - CERTIFICATION "BootNet"

BootNet commence à être utilisée et c'est pourquoi une liste de matériels "Certifiés BootNet" voit le jour. Cette liste permet à tous de vérifier rapidement la compatibilité connue avec des matériels existants.

       
Machines et cartes mère
Marque/Modèle machine
Marque carte mère
Type
Contrôleur réseau
Certifiée
-
Asus

P4P800 Deluxe

3Com Gigabit LOM (3C940)
ok
-

P4P800-VM

Intel Pro 100
ok
-
Via

A7V400-MX

Via Rhine II
ok
Altipro
-
Celeron 433
Realtek 8139
ok
Compaq
-
PI- 333
Realtek 8139
ok
Dell
-
OptiPlex 745
Broadcom
ok
-
Dimension 4600
Intel Pro 100 VE
ok
-
Dimension GX2xx
Intel Pro 1000 MT
ok
-
PowerEdge SC1420
Intel Pro 1000
ok
Toshiba
-
Equiium 3300 (PIII-800 Mhz)
Realtek 8139
ok
-
Equiium 8200 (Celeron 1,7 Ghz)
Intel Pro 100
ok
-
Magna 560s (PIV-2 Ghz)
Intel Pro 100
ok
Zenith
-
Z station 4100 (PII-266/333)
Realtek 8139 PCI
?

 

       
Cartes réseau
Marque
Référence
Chipset
Type
Certifiée
AMD
AMD PCnet VMware Server
-

PCI

ok
Asanté
FAST 10/100 PCI Rev. B Adapter
-

PCI

ok
Davicom
Pro2000WL (10/100 Mb)
DM9102AF

PCI

ok
D-Link
D-LINK DFE 530TX+ PCI (100 Mb)
-

PCI

ok
3Com
Etherlink III PCI 3C590-TPO (10 Mb)
-

PCI

ok
Etherlink XL PCI 3C900B-TPO (10 Mb)
-

PCI

ok
PCI 3C920 compatible (100 Mb)
-

PCI

ok
3CN3AC1556B (10/100 Mb)
-
mini PCI
ok
HP
J2585A DeskDirect 10/100VG NIC
-

PCI

ok
INTEL
E1000 de VMware Server
-

PCI

ok
Realtek
8029AS Combo PCI (10 Mb)
8029AS

PCI

ok
SMC
SMC9332BDT EtherPower 10/100
DEC 21140

PCI

ok

 

La contribution de chacun permettra l'évolution de BootNet.
Il suffit de contacter le webmestre pour lui envoyer les informations par mail.

 

 

XIV) - EVOLUTIONS DES VERSIONS COMPLETES

BootNet évolue... Ce tableau en résume l'historique.

Télécharger
27/11/2006
Version 98SE - Seule cette version est maintenue - Cette version devient la version de base
Ajout des cartes REALTEK RTL8169/8110, RTL8168/8110 et RTL8136/8110 Gigabit
Télécharger
26/09/2006
Version 98SE - Seule cette version est maintenue
Ajout de la carte 3COM 3CN3AC1556B mini PCI
Télécharger
25/08/2006
Version 98SE - Seule cette version est maintenue
Ajout de la carte ADMtek AN993
Télécharger
21/03/2006
Version 98SE - Seule cette version est maintenue
Ajout de la carte INTEL Pro 1000 MT
Télécharger
04/03/2006
Version 98SE - Seule cette version est maintenue
Ajout de la carte 3COM 3C940 et 3C2000
Télécharger
01/02/2006
Version 98SE - Seule cette version sera maintenue
En effet, les utilitaires en mode command sont plus compatibles avec l'interpréteur de 98SE que celui de Me.
Meilleure prise en charge des cartes Realtek RTL8029AS combo 10 Mbits
Ajout de la carte D-LINK DFE 530TX+
Ajout de la carte 3COM 3C905 (3C920 compatible)
Ajout de la prise en charge des cartes Accton EN2242, CheetahPower, LM2247 LM1247, EN1207F
Télécharger
19/04/2005
Version Millenium
Réduction de la taille de NICDET.INI suite aux blocages lors de la détection
Allègement de l'archive NET.LZH (suppression NETH.MSG)
Allègement de l'archive UTILS.LZH (suppression FDISK, FORMAT)
Chargement en mémoire haute du pilote clavier
Télécharger
19/04/2005
Version 98SE.
Cette version ne gère pas l'absence de partition "C" et ne permet pas de formater ni partitionner
Réduction de la taille de NICDET.INI suite aux blocages lors de la détection
Allègement de l'archive NET.LZH (suppression NETH.MSG)
Allègement de l'archive UTILS.LZH (suppression FDISK, FORMAT & GDISK)
Chargement en mémoire haute du pilote clavier
Modification des paramètre de himem dans le fichier CONFIG.SYS
Télécharger
14/03/2005
Ajout de la prise en charge des cartes NetGear FA311/FA312
Mise a jour de fdisk.exe et format.com
Télécharger
23/02/2005
Gestion du clavier français - Suppression message d'erreur furtif.
Télécharger
10/02/2005
Ajout de la prise en charge des cartes HP J2585B DeskDirect 10/100 NIC & J2585A DeskDirect 10/100VG NIC.
Télécharger
09/02/2005
Ajout de la prise en charge de la Realtek 8029AS PCI Combo 10Mbits
Correction de l'ordre des définitions des pilotes dans nicdet.ini
Télécharger
20/01/2005
Ajout de la prise en charge des cartes SIS 900 (sis900.dos). Merci à Denis pour ces infos.
Abandon de xmsdsk.exe et retour de Ramdrive.sys de MS (correction de figeages avec certaines machines)
Télécharger
19/01/2005
Ajout de la prise en charge des cartes SMC (chipset DEC 21040/21041/21140) (smcpwr.dos)
Télécharger
16/01/2005
Ajout de la prise en charge de la carte Marvell Gigabit (Yuknd.dos)
Mise à jour des pilotes Broadcom (B54.dos & B57.dos)
Ajout de la prise en charge des cartes Compaq (N100.dos & Netflx3.dos)
Mise à jour des pilotes Realtek toutes versions (pnpnd.dos, pcind.dos, rtsnd.dos)
Ajout de la prise en charge des cartes IBM Etherjet (ibmfe.dos)
Correction et réorganisation des définitions du fichier Protocol.ini
Télécharger
11/01/2005
Mise à jour du pilote E1000 pour les cartes Intel équipant les Dell série GX2xx (merci à Sébastien)
 
9/12/2004
Correction de blocages suite au démarrage du Ramdrive
Ajout des cartes VIA Rhine (Fetnd.dos)
  27/07/2004 Mise en ligne de la disquette

 

 

A partir de cette disquette, tout est envisageable... Il suffit d'écrire quelques batchs pour enchainer différents traitements automatisés.

Je reste à l'écoute de vos remarques, suggestions et implémentations nouvelles. Je suis aussi à la recherche d'implémentations testées pour de nouvelles cartes réseau.

 

 

Début de page  |  Page d'accueil  |  Me contacter

(C) Laurent - autourdupc.com   -  

Création le 27 juillet 2004.
Mise à jour le 23 septembre 2008.

visites